User Manual

Here are key functionalities offered in ClimateModels.jl.

Climate Model Interface

The interface ties the ModelConfig data structure with methods like setup, build, and launch. In return, it provides standard methods to deal with inputs and outputs, as well as capabilities described below.

The ModelRun method, or just run, streamlines the process. It executes all three steps at once (setup, build, and launch). For example, let's use RandomWalker as the model.

fun=ClimateModels.RandomWalker

With the simplified ModelConfig constructors, we can just write any of the following:

ModelRun(ModelConfig(model=fun))

or

MC=run(ModelConfig(fun))
log(MC)

5-element Vector{String}:
 "f937340 initial setup"
 "18aacb0 add Project.toml to log"
 "9da32e4 add Manifest.toml to log"
 "5d27377 task started [ee69144b-c8b4-4a2e-80f9-cccb68bfa4ce]"
 "609b801 (HEAD -> main) task ended   [ee69144b-c8b4-4a2e-80f9-cccb68bfa4ce]"

or

@ModelRun ClimateModels.RandomWalker

  ID            = 4916bf39-5b52-4e6f-b4d5-8e8759fe5fbc
  model         = RandomWalker
  configuration = anonymous
  run folder    = /tmp/4916bf39-5b52-4e6f-b4d5-8e8759fe5fbc
  log subfolder = /tmp/4916bf39-5b52-4e6f-b4d5-8e8759fe5fbc/log

By design of the ClimateModels interface, it is required that fun receives a ModelConfig as its sole input argument. This requirement is easily satisfied in practice.

Input parameters can be specified via the inputs keyword argument, or via files. See Parameters.

Breaking Things Down

Let's start with defining the model:

MC=ModelConfig(model=fun)

  ID            = b89489bc-1ecf-45e8-83a5-e49097a5fec3
  model         = RandomWalker
  configuration = anonymous
  run folder    = /tmp/b89489bc-1ecf-45e8-83a5-e49097a5fec3
  log subfolder = /tmp/b89489bc-1ecf-45e8-83a5-e49097a5fec3/log

The sequence of calls within ModelRun is expanded below. In practice, setup typically handles files and software, build gets the model ready, and launch starts the model computation.

setup(MC)
build(MC)
launch(MC)

The model's top level function gets called via launch. In our example, it generates a CSV file found in the run folder as shown below.

Sometimes it is convenient to further break down the computational workflow into several tasks. These can be added to the ModelConfig via put! and then executed via launch, as demonstrated in Parameters.

The run folder name and its content can be viewed using pathof and readdir, respectively.

pathof(MC)

"/tmp/b89489bc-1ecf-45e8-83a5-e49097a5fec3"

readdir(MC)

2-element Vector{String}:
 "RandomWalker.csv"
 "log"

The log subfolder was created earlier by setup. The log function can then retrieve the workflow log.

log(MC)

5-element Vector{String}:
 "fe37e0a initial setup"
 "0d2399f add Project.toml to log"
 "36050d7 add Manifest.toml to log"
 "3f85313 task started [0066d68f-1271-463b-aae0-c93f72b619f2]"
 "a375e87 (HEAD -> main) task ended   [0066d68f-1271-463b-aae0-c93f72b619f2]"

This highlights that Project.toml and Manifest.toml for the environment being used have been archived. This happens during setup to document all dependencies and make the workflow reproducible.

Customization

A key point is that everything can be customized to, e.g., use popular models previously written in Fortran or C just as simply.

Here are simple ways to start usinf the ClimateModels.jl interface with your favorite model.

• specify model directly as a function, and use defaults for everything else, as illustrated in random walk
• specify model name as a String and the main Function as the configuration, as in CMIP6
• put model in a Pluto notebook and ingest it via PlutoConfig as shown below

Sometimes, one may also want to define custom setup, build, or launch methods. To do this, one can define a concrete type of AbstractModelConfig using ModelConfig as a blueprint. This is the recommended approach when other languanges like Fortran or Python are involved (e.g., Hector.

For popular models the customized interface elements can be provided via a dedicated package. This may allow them to be maintained independently by developers and users most familiar with each model. MITgcmTools.jl does this for MITgcm. It provides its own suite of examples that use the ClimateModels.jl interface.

Tracked Worklow Support

When creating a ModelConfig, it receives a unique identifier (UUIDs.uuid4()). By default, this identifier is used in the name of the run folder attached to the ModelConfig.

The run folder normally gets created by setup. During this phase, log is used to create a git enabled subfolder called log. This will allow us to record steps in our workflow – again via log.

As shown in the Parameters example:

• Parameters specified via inputs are automatically recorded into tracked_parameters.toml during setup.
• Modified parameters are automatically recorded in tracked_parameters.toml during launch.
• log called on a ModelConfig with no other argument shows the workflow record.

Parameters

Let's now mofdify model parameters, then rerun a model, and keep track of these workflow steps.

After an initial model run of 100 steps, duration NS is extended to 200 time steps. The put! and launch sequence then reruns the model.

mc=ModelConfig(fun,(NS=100,filename="run01.csv"))
run(mc)

mc.inputs[:NS]=200
mc.inputs[:filename]="run02.csv"
put!(mc)
launch(mc)

log(mc)

9-element Vector{String}:
 "9d59d22 initial setup"
 "0e8c524 initial tracked_parameters.toml"
 "c35f97f add Project.toml to log"
 "898411a add Manifest.toml to log"
 "05d6f79 task started [70221ea1-191c-4b16-a083-cee8f3151a3e]"
 "568e127 task ended   [70221ea1-191c-4b16-a083-cee8f3151a3e]"
 "41a4834 task started [d96a818f-8b6e-4c95-91c3-ed8f08ae5f45]"
 "4eb6588 modify tracked_parameters.toml"
 "28d241b (HEAD -> main) task ended   [d96a818f-8b6e-4c95-91c3-ed8f08ae5f45]"

The call sequence is readily reflected in the workflow log, and the run folder now has two output files.

readdir(mc)

3-element Vector{String}:
 "log"
 "run01.csv"
 "run02.csv"

In more complex models, there generally is a large number of parameters that are often organized in a collection of text files.

The ClimateModels.jl interface is easily customized to turn those into a tracked_parameters.toml file as demonstrated in the Hector and in the MITgcm.

ClimateModels.jl thus readily enables interacting with parameters and tracking their values even with complex models as highlighted in the JuliaCon 2021 Presentation.

Pluto Notebook Integration

Any Pluto notebook is easily integrated to the ClimateModels.jl framework via PlutoConfig.

filename=joinpath(tempdir(),"notebook.jl")
PC=PlutoConfig(filename,(linked_model="MC",))
run(PC)
readdir(PC)

The Pluto notebook gets split up into main code (1) and environment (2). This approach provides a simple way to go from model documentation, in notebook format, to large simulations run, done in batch mode.

Files get copied into pathof(PC) as before. If notebook.jl contains a ModelConfig, let's call it MC, then the pathof(MC) folder can be linked into pathof(PC) at the end. This feature is controlled by linked_model as illustrated just before. A data input folder can be specified via the data_folder key. This will result in the specified folder getting linked into pathof(PC) before running the notebook.

update provides a simple method for updating notebook dependencies. Such routine maintanance is often followed by rerunning the notebook to detect potential updating issues.

update(PlutoConfig(filename))
run(PlutoConfig(filename))
nothing # hide

Files and Cloud Support

Numerical model output often gets archived, distributed, and retrieved over the web. Some times, downloading data is most convenient. In other cases, it is preferable to compute in the cloud and just download final results.

ClimateModels.jl has examples for most common file formats. These are handled via Downloads.jl, NetCDF.jl, DataFrames.jl, CSV.jl, and TOML.jl.

fil=joinpath(pathof(mc),"run02.csv")

CSV=ClimateModels.CSV
DataFrame=ClimateModels.DataFrame

CSV.File(fil) |> DataFrame

"200×2 DataFrame"